Tcl/Tk Curso On-Line de Programação

O widget text

O widget text oferece uma área para renderização de hyper-texto, que pode ser desde texto baseado nas tags Tk até SGML, HTML e XML. Para renderização de texto HTML pode-se usar a biblioteca HTML Library 0.3, já para trabalhar com XML ou SGML é preciso utilizar o parser TclXML 1.2 e implementar as rotinas para renderizar o documento. A biblioteca HTML Library 0.3 suporta apenas HTML 2.0. Pode ser uma boa ocasião para começar-mos a pensar em implementar um motor para HTML 4, usando TclXML.

Veja como o widget text é poderoso:

A imagem acima mostra o browser TkShip que eu implementei utilizando o widget text e a biblioteca HTML Library 0.3. Fiz algumas modificações na biblioteca, mas foi apenas para melhorar o aspecto da pagina.

Você pode obter o mesmo efeito, inserindo texto no widget e configurando tags Tk para cada parte do documento, mas isso, em geral, não vale a pena. É melhor usar HTML.

Veja um exemplo:

toplevel .t

text .t.text

pack .t.text -expand 1 -fill both

.t.text tag configure AZUL -foreground blue

.t.text tag configure VERMELHO -foreground red

.t.text insert end "Esta é uma linha em texto NORMAL.\n"

.t.text insert end "Esta é uma linha em texto AZUL.\n"

.t.text insert end "Esta é uma linha em texto VERMELHO.\n"

.t.text tag add AZUL 2.0 2.31

.t.text tag add VERMELHO 3.0 3.35

Vejamos agora cada uma das opções suportadas pelo widget text:
 

Os comandos suportados pelo widget text são:
 

O widget text suporta os seguintes índices, na forma base modificador:

Base: linha.coluna, @X,Y, end, marca, tag.first, tag.last, caminho_para_a_janela_embutida, nome_da_imagem.

Modificador: + ou -contadorchars, + ou - contador lines, linestart, lineend, wordstart, wordend.

As tags suportam as seguintes opções, além daquelas suportadas pelo widget text:
 

As janelas embutidas suportam as seguintes opções:
 

As imagens embutidas suportam as seguintes opções:
 

Exemplos

O exemplo a seguir foi adaptado do material que acompanha o Kit de instalação do Tcl/Tk 8.3.1:
 

#

# Este script cria um widget text que ilustra os vários tipos de estilos que podem

# ser configurados para as tags

#

# Desenha a janela

set w .style

catch {destroy $w}

toplevel $w

wm title $w "Demonstração do widget Text - Estilos"

wm iconname $w "style"

frame $w.buttons

pack $w.buttons -side bottom -fill x -pady 2m

button $w.buttons.dismiss -text Fechar -command "destroy $w"

pack $w.buttons.dismiss -side left -expand 1

text $w.text -yscrollcommand "$w.scroll set" -setgrid true -width 70 -height 32 -wrap word

scrollbar $w.scroll -command "$w.text yview"

pack $w.scroll -side right -fill y

pack $w.text -expand yes -fill both

# Configura os estilos

$w.text tag configure bold -font {Courier 12 bold italic}

$w.text tag configure big -font {Courier 14 bold}

$w.text tag configure verybig -font {Helvetica 24 bold}

if {[winfo depth $w] > 1} {

    $w.text tag configure color1 -background #a0b7ce

    $w.text tag configure color2 -foreground red

    $w.text tag configure raised -relief raised -borderwidth 1

    $w.text tag configure sunken -relief sunken -borderwidth 1

} else {

    $w.text tag configure color1 -background black -foreground white

    $w.text tag configure color2 -background black -foreground white

    $w.text tag configure raised -background white -relief raised -borderwidth 1

    $w.text tag configure sunken -background white -relief sunken -borderwidth 1

}

$w.text tag configure bgstipple -background black -borderwidth 0 -bgstipple gray12

$w.text tag configure fgstipple -fgstipple gray50

$w.text tag configure underline -underline on

$w.text tag configure overstrike -overstrike on

$w.text tag configure right -justify right

$w.text tag configure center -justify center

$w.text tag configure super -offset 4p -font {Courier 10}

$w.text tag configure sub -offset -2p -font {Courier 10}

$w.text tag configure margins -lmargin1 12m -lmargin2 6m -rmargin 10m

$w.text tag configure spacing -spacing1 10p -spacing2 2p -lmargin1 12m -lmargin2 6m -rmargin 10m

# Insere o texto

$w.text insert end {Widgets Text como este permitem a você exibir informações em uma variedade de estilos.

A exibição de estilos é controlada por um mecanismo chamado }

$w.text insert end tags bold

$w.text insert end {. Tags são apenas nomes que você pode aplicar a um ou mais caracteres em um widget text.

Você pode configurar tags com vários estilos.

Se você fizer isso, os caracteres rotulados serão exibidos com o estilo que você escolher.

Os estilos disponíveis são:}

$w.text insert end "\n1. Fonte." big

$w.text insert end "Você pode escolher qualquer fonte X, "

$w.text insert end grande verybig

$w.text insert end " ou "

$w.text insert end "pequena.\n"

$w.text insert end "\n2. Cor." big

$w.text insert end "Você pode determinar tanto a "

$w.text insert end "cor de fundo" color1

$w.text insert end " como "

$w.text insert end "a cor de primeiro plano" color2

$w.text insert end "\n, ou "

$w.text insert end ambas {color1 color2}

$w.text insert end ".\n"

$w.text insert end "\n3. Padrão." big

$w.text insert end "Você pode modificar tando o "

$w.text insert end fundo bgstipple

$w.text insert end " como o "

$w.text insert end "primeiro plano." fgstipple

$w.text insert end {Fazendo com que as informações sejam desenhadas utilizando um bitmap, ao invés de uma cor sólida.}

$w.text insert end "\n4. Sublinhado." big

$w.text insert end "Você pode "

$w.text insert end sublinhar underline

$w.text insert end " faixas de texto.\n"

$w.text insert end "\n5. Riscado." big

$w.text insert end "Você pode "

$w.text insert end riscar overstrike

$w.text insert end " faixas de texto.\n"

$w.text insert end "\n6. Efeitos 3-D." big

$w.text insert end {Você pode modificar o fundo, para que ele seja desenhado com bordas que farão os caracteres parecerem estar }

$w.text insert end "em alto relevo" raised

$w.text insert end " ou "

$w.text insert end "em baixo relevo" sunken

$w.text insert end ".\n"

$w.text insert end "\n7. Alinhamento." big

$w.text insert end "Você pode fazer com que as linhas sejam\n"

$w.text insert end "alinhadas pela esquerda,\n"

$w.text insert end "alinhadas pela direita, ou\n" right

$w.text insert end "centralizadas.\n" center

$w.text insert end "\n8. Sobre-escrido e sub-escrito."  big

$w.text insert end "Você pode controlar a "

$w.text insert end "posição vertical do texto para criar sobre-escritos como 10"

$w.text insert end "n" super

$w.text insert end " ou sub-escritos como X"

$w.text insert end "i" sub

$w.text insert end ".\n"

$w.text insert end "\n9. Margens." big

$w.text insert end "Você pode controlar o espaçamento lateral"

$w.text insert end " em\ncada lado do texto:\n"

$w.text insert end "Este parágrafo é um exemplo de uso de " margins

$w.text insert end "margens. Ele consiste de uma simples linha de texto " margins

$w.text insert end "quebrada na tela. Existem duas especificações " margins

$w.text insert end "para margens à esquerda, uma para a primeira linha " margins

$w.text insert end "exibida, associada com a linha de texto, " margins

$w.text insert end "e uma para as linha subsequentes,  " margins

$w.text insert end "que serão quebradas caso necessário. Há também uma " margins

$w.text insert end "especificação separada para a margem direita, " margins

$w.text insert end "a qual é usada para determinar o ponto para a quebra de linha.\n" margins

$w.text insert end "\n10. Espaçamento." big

$w.text insert end "Você pode controlar o espaço entre linhas com três\n"

$w.text insert end "parâmetros separados. \"Spacing1\" determina "

$w.text insert end "o espaço extra deixado\nsobre uma linha, \"spacing3\" "

$w.text insert end "determina o espaço extra deixado abaixo de uma linha,\ne "

$w.text insert end "e se a linha de texto será quebrada, \"spacing2\" determina o "

$w.text insert end "espaço extra deixado\nentre as linhas "

$w.text insert end "que compõem o texto.\n"

$w.text insert end "Este parágrafo endentado, ilustra como o espaçamento " spacing

$w.text insert end "pode ser usado. Cada parágrafo, é uma " spacing

$w.text insert end "única linha no widget text, o qual sofre " spacing

$w.text insert end "uma quebra de linha gerada pelo widget.\n" spacing

$w.text insert end "Spacing1 está configurado para 10 pontos neste texto, " spacing

$w.text insert end "o que resulta em saltos relativamente grandes entre " spacing

$w.text insert end "os parágrafos. Spacing2 está configurado para 2 pontos, " spacing

$w.text insert end "oque resulta em apenas um pequeno espaçamento " spacing

$w.text insert end "no parágrafo. Spacing3 não está sendo usado " spacing

$w.text insert end "neste exemplo.\n" spacing

$w.text insert end "Para ver como o espaçamento funciona, selecione uma faixa de texto " spacing

$w.text insert end "neste parágrafo. A seleção " spacing

$w.text insert end "cobrirá o espaçamento adicional." spacing

É isso. Copie e cole o fragmento de código acima na linha de comando do wish. Você obterá a janela abaixo:

Para uma descrição detalhada de todos os comandos disponíveis em Tk, consulte a documentação on-line, ou o Tcl/Tk Reference Guide, ou ainda o Tcl/Tk Electronic Reference.

Para maiores informações envie e-mail para info@souzamonteiro.com.